Main Page

From lhenguabase
Jump to navigation Jump to search

Bem-vindo à Lhenguabase

A Lenguabase é um repositório de dados lexicográficos do mirandês, alojado na wikibase.cloud. Esta instância Wikibase tem como objetivo documentar a língua mirandesa de forma aberta e colaborativa. Por usar uma instância Wikibase, este repositório tem ligação direta à web semântica e multilingue, comportada pela Wikidata, à imagem de outras línguas minoritárias como o basco.

História

O mirandês foi reconhecido como segunda língua oficial de Portugal em 1999. Apesar deste reconhecimento e da sua integração nos curricula escolares do concelho de Miranda do Douro, o mirandês enfrenta uma situação de ameaça, caracterizada por um número reduzido de falantes e pela escassez de recursos digitais dedicados à sua documentação e revitalização. Um dicionário, além de ser um recurso essencial para a documentação linguística, desempenha um papel fundamental como ferramenta didática na sala de aula. É especialmente importante no contexto da sua inclusão nos curricula escolares de Miranda do Douro. Assim, um grupo de investigadores em Linguística e wikimedistas, promoveu, em conjunto com a comunidade mirandesa, uma oficina sobre "Lexicografia e sustentabilidade linguística" na Faculdade de Letras da Universidade do Porto, em que nasceu a Lhenguabase.

Objetivos

A disponibilização de um dicionário adaptado ao público escolar pode facilitar o processo de ensino-aprendizagem, proporcionando aos estudantes acesso direto a vocabulário, expressões e usos gramaticais do mirandês de forma clara e acessível, tal como no português. Para além disso, um dicionário desse tipo incentiva o uso ativo da língua, contribuindo para a valorização da identidade cultural e linguística local. Ao incorporar exemplos de uso contextualizados, orientações sobre pronúncia e informações culturais associadas às palavras, esta ferramenta pode tornar-se um recurso interativo que motiva os alunos a explorar e a utilizar o mirandês de forma prática e significativa, promovendo, assim, a sua revitalização. Finalmente, o conhecimento do vocabulário mirandês é de extrema importância também para os alunos de português, uma vez que esclarece conceitos como a continuidade dialetal, a mudança histórica e o contacto de línguas.

Origem e inserção de dados

A maioria dos dados iniciais da Lhenguabase foi extraída do Wikcionário do português, dando uma instância própria ao mirandês. O melhoramento desde projeto, quer com a adição de novos lexemas, quer com a inserção de mais informações dentro de cada lexema é livre. No entanto, cada edição é validada por um falante nativo de mirandês e um lexicógrafo, antes de se considerar pronta para uma partilha mais abrangente.

Pages in this Wikibase

Recursos de l Mirandés

Lexical Entries, senses and glosses

#title: All lexical entries with glosses in MWL and PT

PREFIX lwb: <https://lhenguabase.wikibase.cloud/entity/>
PREFIX ldp: <https://lhenguabase.wikibase.cloud/prop/direct/>

select ?lexical_entry ?wikidata ?posLabel ?lemma ?sense ?gloss_mwl ?gloss_pt
       
where { 
  ?lexical_entry wikibase:lemma ?lemma; wikibase:lexicalCategory ?pos; ontolex:sense ?sense.
  optional {?sense skos:definition ?gloss_pt filter(lang(?gloss_pt)="pt").}
  optional {?sense skos:definition ?gloss_mwl filter(lang(?gloss_mwl)="mwl").}
  optional {?lexical_entry ldp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
}

Try it!

Lexical Entries and usage examples

#title: All lexical entries with usage examples

PREFIX lwb: <https://lhenguabase.wikibase.cloud/entity/>
PREFIX ldp: <https://lhenguabase.wikibase.cloud/prop/direct/>

select ?lexical_entry ?wikidata ?posLabel ?lemma (str(?example) as ?usage_example)
       
where { 
  ?lexical_entry wikibase:lemma ?lemma; wikibase:lexicalCategory ?pos; ontolex:sense ?sense.
  optional {?lexical_entry ldp:P14 ?example.}
  optional {?lexical_entry ldp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
} order by desc(?usage_example)

Try it!


Lexical Entries that have been cloned on Wikidata

For cloning lexemes, this script was used.

#title: All lexical entries that have been cloned on Wikidata

PREFIX lwb: <https://lhenguabase.wikibase.cloud/entity/>
PREFIX ldp: <https://lhenguabase.wikibase.cloud/prop/direct/>

select distinct ?lexical_entry ?wikidata ?posLabel ?lemma ?sense ?gloss ?back_alignment_from_clonation
       
where { 
  ?lexical_entry wikibase:lemma ?lemma; wikibase:lexicalCategory ?pos; ontolex:sense ?sense.
  optional {?sense skos:definition ?gloss.}
  ?lexical_entry ldp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  SERVICE <https://query.wikidata.org/sparql> {
           select ?wikidata ?back_alignment_from_clonation where {
             ?wikidata p:P1343 [ps:P1343 wd:Q131756013; pq:P973 ?back_alignment_from_clonation].
             }}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mwl,pt". }
} order by desc(?wikidata)

Try it!


Ontology classes and instances

#title:Ontology classes, number of instances, example of instance
PREFIX lwb: <https://lhenguabase.wikibase.cloud/entity/>
PREFIX ldp: <https://lhenguabase.wikibase.cloud/prop/direct/>
PREFIX lp: <https://lhenguabase.wikibase.cloud/prop/>
PREFIX lps: <https://lhenguabase.wikibase.cloud/prop/statement/>
PREFIX lpq: <https://lhenguabase.wikibase.cloud/prop/qualifier/>
PREFIX lpr: <https://lhenguabase.wikibase.cloud/prop/reference/>
PREFIX lno: <https://lhenguabase.wikibase.cloud/prop/novalue/>

SELECT ?class ?classLabel (count(?item) as ?instances) (sample(?item) as ?example_instance)  WHERE {
?class ldp:P5 lwb:Q1.
optional{?item ldp:P5 ?class.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "mwl,pt,en". }
} group by ?class ?classLabel ?instances ?example_instance  order by desc(?instances)

Try it!

Wikidata alignments

#title: All wikidata alignments

PREFIX lwb: <https://lhenguabase.wikibase.cloud/entity/>
PREFIX ldp: <https://lhenguabase.wikibase.cloud/prop/direct/>

select ?lh ?lh_id ?wd ?wd_id where {
  ?lh ldp:P1 ?wd_id.
  bind(iri(concat(str(wd:),?wd_id)) as ?wd)
  bind(strafter(str(?lh),str(lwb:)) as ?lh_id)
  }

Try it!